/\*

Simulation of a randomized controlled trial, with a single pre-test and two post-tests, post1 and post2.

The analysis is aimed at taking into account differences in the error of measurement between control and

experimental groups in the post-test. Such differences confound the estimation of individual responses.  
 Two (or more) post tests are needed to estimate and adjust for the different errors, under the assumption   
 that the two post-tests are sufficiently close together for the individual responses not to change

between the two post-tests.

The simulation allows for individual responses in the post-tests in both groups. The individual responses

in the control group represent changes in indviduals that might occur in the time between the pre and

post tests. Hence the individual responses in the control group are added to the exptal group, while the

exptal group has extra individual responses added to it. These are the net individual responses due to

the treatment, and the aim of the analysis is to estimate these and also the net mean change in the post

test.

Measurement errors are the same in control and exptal groups in the pre test. Measurement error is different

in control and exptal groups in the post-test, but it is the same in both post-tests within each group.

This version generates data for a gender effect, but the gender effect is not estimated.

If you have a gender or other group effect (other than the control vs exptal), you should perform

separate analyses for the groups to properly account for and estimate separate errors, individual

responses, treatment effects and modifying effects of covariates. Compare the errors and effects

using the combine/compare effects spreadsheet at sportsci.org.

The linear effects of pre-test VO2max and another covariate X are also estimated, but the simulation

does not generate effects for these two variables.

This simulation includes estimation of proportions of responders in the simulated samples, but there is  
 no estimation of the chances that each individual is a responder, owing to difficulties when there are  
 two or more post-tests.

There is bootstrapping of all confidence limits except those for the covariates. Confidence limits of

MBI chances are also bootstrapped, for comparison with those derived via the non-central t statistic.

This program runs in SAS Studio or the full SAS program (with output to the listing window).

It is set to run 10 simulated trials. Many more are needed to properly assess the confidence limits.

Bootstrapping is also set to run only 100 bootstrapped samples. 3000 are needed to properly estimate

bootstrapped confidence limits, but the program will take many hours to run and may run out of memory.

\*/

options notes nodate number stimer; \*unstar to debug;

\*options nonotes nodate number stimer; \*unstar when running a full simulation;

\*ods \_ALL\_ close; \*unstar this if want output only to the listing window in the main SAS package;

ods graphics off;

ods listing;

run;

ods select all;

options ps=61 ls=110 pageno=1 nodate;

\*generate data;

\*the most important values to play with are shown highlighted;

%let dep=VO2maxDelta; \*also works for VO2maxPost, with right mix of sample size, SD and ExpSD;

%let NoOfTrials=10;

%let ss=40; \*sample size in each of the two groups;

%let Mean=40; \*in ml/min/kg;

%let SD=7; \*ditto;

%let errorpre=2; \*2 is equivalent to 2/40\*100=5%;

%let errorpostctl=2.5;

%let errorpostexp=1.5;

%let Magnithresh=1.5; \*if SD=7, 1.5 is equivalent to 1.5/SD = 1.5/7 = 0.21. Default smallest important=0.20;

%let ExpMean=4.0; \*net mean effect of treatment, 4.0 is equivalent to 4.0/mean\*100 = 10%, if mean=40;

%let CtlSD=1; \*SD of individual responses in control group, representing stable changes;

%let ExpSD=3; \*extra SD of individual responses in exptal group, must be >=|Xsd\*Xslope|;

%let FemaleMean=0; \*male mean will be set to equal and opposite; \*not used here;

%let Xmean=1; \*mean of a covariate, e.g. log2(h/wk mod-vig activity), so 1 represents 2 h/wk;

%let Xsd=1; \*sd of above covariate, so 1 represents a (factor) SD of ×⁄÷2;

%let Xslope=0; \*change in ExpMean per unit of difference of X from Xmean;

\*If Xmean=1, Xslope=-1, ExpMean=4.5, then, e.g. for X=3, treatment effect = ExpMean-1\*(3-1) = 4.5-2 = 2.5;

%let bootss=100; \*set this to 3000 when running full simulation;

%let alpha=0.1; \*alpha level for confidence limits;

%let nob=nobound; \*allow negative variance in the mixed model;

%let logflag=0; \*set to 1 for log transformation, not used for these simulations;

%let deceffect=1; \*decimal place for the effects;

%let decdep=1; \*decimal place for the means and SD of the dependent;

title1 "&dep RCT, smallest effect=&Magnithresh, net mean change=&ExpMean, control SDir=&CtlSD, extra expt SDir=&ExpSD";

title2 "Pre-test: mean=&mean, SD=&sd, error=&errorpre Post-test: ctrl error=&errorpostctl, expt error=&errorpostexp";

title3 "Xmean=&Xmean, Xsd=&Xsd, Xslope=&Xslope (effect on indiv responses per unit of X); group sample size=&ss";

title4 "Female mean extra individual response=&FemaleMean; male mean extra=-&FemaleMean";

title4 "No gender effect in these simulations"; \*star this off when including Gender;

data dat1;

do Trial=1 to &NoOfTrials;

Group="Control";

xVarExp=0;

xVarCtl=1;

do SubjectID=1 to &ss;

Gender="Female";

if mod(SubjectID,2)=0 then Gender="Male";

VO2maxTrue=&Mean+rannor(0)\*&SD;

VO2maxPre=VO2maxTrue+rannor(0)\*&errorpre;

X=&Xmean+rannor(0)\*&Xsd; \*random normal covariate;

IndivResponse=rannor(0)\*&CtlSD;

VO2maxPost1=VO2maxTrue+rannor(0)\*&errorpostctl+IndivResponse;

VO2maxDelta1=VO2maxPost1-VO2maxPre;

VO2maxPost2=VO2maxTrue+rannor(0)\*&errorpostctl+IndivResponse;

VO2maxDelta2=VO2maxPost2-VO2maxPre;

output;

end;

Group="Exptal";

xVarExp=1;

xVarCtl=0;

do SubjectID=&ss+1 to 2\*&ss;

Gender="Female";

if mod(SubjectID,2)=0 then Gender="Male";

VO2maxTrue=&Mean+rannor(0)\*&SD;

VO2maxPre=VO2maxTrue+rannor(0)\*&errorpre;

X=&Xmean+rannor(0)\*&Xsd; \*random normal covariate;

IndivResponse=&ExpMean+(X-&Xmean)\*&Xslope+sqrt(&ExpSD\*\*2-(&Xsd\*&Xslope)\*\*2)\*rannor(0)

+&FemaleMean-2\*(Gender="Male")\*&FemaleMean+rannor(0)\*&CtlSD;

VO2maxPost1=VO2maxTrue+rannor(0)\*&errorpostexp+IndivResponse;

VO2maxDelta1=VO2maxPost1-VO2maxPre;

VO2maxPost2=VO2maxTrue+rannor(0)\*&errorpostexp+IndivResponse;

VO2maxDelta2=VO2maxPost2-VO2maxPre;

output;

end;

end;

/\*

title6 "First few observations";

options ls=175;

proc print data=dat1(obs=40);

format VO2maxTrue--VO2maxDelta2 5.1;

run;

\*/

options ls=110 ps=70 pageno=1;

title6 "Basic stats for first trial";

proc means mean std min max maxdec=1 fw=7 data=dat1;

var VO2maxPre VO2maxPost1 VO2maxPost2 VO2maxDelta1 VO2maxDelta2 X IndivResponse;

class Group ;

\*by Trial;

where Trial=1;

run;

title6 "Population proportions of net responders";

data props;

ExpSD=&ExpSD;

if ExpSD=0 then ExpSD=1E-7;

PropPosResponders=100\*(1-probnorm(-(&ExpMean-&MagniThresh)/ExpSD));

PropNegResponders=100\*probnorm(-(&magnithresh+&ExpMean)/ExpSD);

PropTrivResponders=100-PropPosResponders-PropNegResponders;

drop ExpSD;

DataGroup="Popn";

\*need the above dataset without gender effect for comparison with derived unexplained SDir;

\*no, use the next dataset now;

data props1;

DataGroup="Popn";

ExpSD=&ExpSD;

if ExpSD=0 then ExpSD=1E-7;

do Gender="Both";

\*do Gender="Female","Male";

PropPosResponders=

100\*(1-probnorm(-(&ExpMean+&FemaleMean-2\*(Gender="Male")\*&FemaleMean-&MagniThresh)/ExpSD));

PropNegResponders=

100\*probnorm(-(&magnithresh+&FemaleMean-2\*(Gender="Male")\*&FemaleMean+&ExpMean)/ExpSD);

PropTrivResponders=100-PropPosResponders-PropNegResponders;

output;

end;

drop ExpSD;

proc print noobs data=props1;

var Gender PropNegResponders PropTrivResponders PropPosResponders;

format \_numeric\_ 5.1;

run;

proc sort data=dat1;

by Trial Group SubjectID;

proc means noprint data=dat1;

var VO2maxPre;

output out=maxN(drop=\_type\_ \_freq\_) n=max;

by Trial Group;

\*proc print data=maxn;run;

\*%macro bootdisp;

data bootsample;

set maxN;

do Sample=1 to &bootss;

do BootSubjN=1 to max;

SubjectN=ceil(max\*ranuni(0));

output;

end;

end;

\*proc print data=bootsample;run;

data dat2;

set dat1;

by Trial Group;

retain SubjectN;

if first.Group then SubjectN=0;

SubjectN=SubjectN+1;

keep Trial subjectN SubjectID Group Gender VO2maxPre VO2maxPost1 VO2maxPost2 VO2maxDelta1 VO2MaxDelta2

X xVarExp xVarCtl IndivResponse;

\*proc print data=dat2;run;

\*data bootdat;

\*make cartesian product of the two data sets;

proc sql;

create table bootdat as

select \*

from dat2 as r, bootsample as l

where l.SubjectN=r.SubjectN and l.Trial=r.Trial and l.Group=r.Group;

quit;

run;

/\*

proc sort;

by Trial sample group subjectN;

options ls=130 ps=61;

proc print;run;

\*/

data bootdat1;

set dat2(in=a) bootdat;

if a then do;

Sample=0;

DataGroup="Orig";

BootSubjN=SubjectN; \*gives subject ID in original data the same name as in the boot data;

end;

else DataGroup="boot";

if Group="Exptal" then BootSubjN=BootSubjN+1000;

drop max;

Gender="Both"; \*star this off when including Gender;

proc sort;

by Trial DataGroup Sample;

\*proc print data=bootdat1;run;

proc standard data=bootdat1 mean=0 std=0.5 out=bootdat2;

var VO2maxPre X;

by Trial DataGroup Sample;

\*make dataset in long format for the two post tests;

data bootdat3;

set bootdat2;

Time="Post1";

&dep=&dep.1;

output;

Time="Post2";

&dep=&dep.2;

output;

run;

proc sort;

by Trial DataGroup Sample BootSubjN;

\*set up a star to suppress titles with (raw) when not using log transformation;

data \_null\_;

if "&logflag"="1" then call symput('star',"\*");

else call symput('star',"");

run;

data clev pred pred1 pred2 predm predm1 est est1 estCohen lsm lsm1 lsmdiff lsmdiff1 lsmdiff2

cov cov0 cov1 cov2 cov3 covsum solf solf1 solr solr1;

data pred0a predm0a cov0a est0a lsmdiff0a;

run;

ods select none; \*for running in SAS Studio;

ods listing close;

\*mixed model with usual extra variance in exptal group;

proc mixed data=bootdat3 covtest cl alpha=&alpha &nob;

class BootSubjN Group Gender Time;

model &dep=Group Group\*Time Group\*VO2maxPre Group\*X/s ddfm=sat outp=pred0a residual noint; \*outpm=predm0a;

\*model VO2maxPost=Group Group\*VO2maxPre Group\*X Group\*Gender/s ddfm=sat outp=pred outpm=predm residual noint;

random int xVarExp/subject=BootSubjN s cl alpha=&alpha;

repeated/group=Group;

lsmeans Group/diff=control('Control') alpha=&alpha; \*star this off when including Gender;

\*lsmeans Group\*Gender/diff=control('Control' 'Male') alpha=&alpha; \*unstar when including Gender;

\*lsmeans Group\*Gender/diff=control('Control' 'Female') alpha=&alpha; \*unstar when including Gender;

estimate "Effect of 2SD of VO2maxPre:";

estimate " Control 2SD of VO2maxPre" Group\*VO2maxPre 1 0/cl alpha=&alpha;

estimate " Exptal 2SD of VO2maxPre" Group\*VO2maxPre 0 1/cl alpha=&alpha;

estimate " Expt-Cont 2SD of VO2maxPre" Group\*VO2maxPre -1 1/cl alpha=&alpha;

estimate "Effect of 2SD of X:";

estimate " Control 2SD of X" Group\*X 1 0/cl alpha=&alpha;

estimate " Exptal 2SD of X" Group\*X 0 1/cl alpha=&alpha;

estimate " Expt-Cont 2SD of X" Group\*X -1 1/cl alpha=&alpha;

ods output covparms=cov0a;

ods output estimates=est0a;

ods output lsmeans=lsm0a;

ods output diffs=lsmdiff0a;

\*ods output solutionr=solr;

\*ods output solutionf=solf;

\*ods output classlevels=clev;

by Trial DataGroup Sample;

run;

data filtera;

set cov0a(keep=Trial DataGroup Sample covparm estimate);

if covparm="xVarExp";

if estimate>0 then Variance="Pos";

drop estimate covparm;

data pred0b predm0b cov0b est0b lsmdiff0b;

\*mixed model with extra variance in control group;

proc mixed data=bootdat3 covtest cl alpha=&alpha &nob;

class BootSubjN Group Gender Time;

model &dep=Group Group\*Time Group\*VO2maxPre Group\*X/s ddfm=sat outp=pred0b residual noint; \* outpm=predm0b;

\*model VO2maxPost=Group Group\*VO2maxPre Group\*X Group\*Gender/s ddfm=sat outp=pred outpm=predm residual noint;

random int xVarCtl/subject=BootSubjN s cl alpha=&alpha;

repeated /group=Group;

lsmeans Group/diff=control('Control') alpha=&alpha; \*star this off when including Gender;

\*lsmeans Group\*Gender/diff=control('Control' 'Male') alpha=&alpha; \*unstar when including Gender;

\*lsmeans Group\*Gender/diff=control('Control' 'Female') alpha=&alpha; \*unstar when including Gender;

estimate "Effect of 2SD of VO2maxPre:";

estimate " Control 2SD of VO2maxPre" Group\*VO2maxPre 1 0/cl alpha=&alpha;

estimate " Exptal 2SD of VO2maxPre" Group\*VO2maxPre 0 1/cl alpha=&alpha;

estimate " Expt-Cont 2SD of VO2maxPre" Group\*VO2maxPre -1 1/cl alpha=&alpha;

estimate "Effect of 2SD of X:";

estimate " Control 2SD of X" Group\*X 1 0/cl alpha=&alpha;

estimate " Exptal 2SD of X" Group\*X 0 1/cl alpha=&alpha;

estimate " Expt-Cont 2SD of X" Group\*X -1 1/cl alpha=&alpha;

ods output covparms=cov0b;

ods output estimates=est0b;

ods output lsmeans=lsm0b;

ods output diffs=lsmdiff0b;

\*ods output solutionr=solr;

\*ods output solutionf=solf;

\*ods output classlevels=clev;

by Trial DataGroup Sample;

run;

data filterb;

set cov0b(keep=Trial DataGroup Sample covparm estimate);

if covparm="xVarCtl";

if estimate>0 then Variance="Pos";

drop estimate covparm;

ods listing;

ods select all;

/\*

proc print data=cov0a;

where sample=0;

run;

\*/

\*proc print data=filtera; run;

\*proc print data=filterb;run;

data lsm0a;

merge lsm0a filtera;

by Trial DataGroup Sample;

if Variance="Pos";

\*drop Variance;

data lsm0b;

merge lsm0b filterb;

by Trial DataGroup Sample;

if Variance="Pos";

drop Variance;

data lsm;

set lsm0a lsm0b;

Gender="Both"; \*star this off when including Gender;

run;

proc sort;

by Trial DataGroup Sample;

data lsmdiff0a;

merge lsmdiff0a filtera;

by Trial DataGroup Sample;

if Variance="Pos";

\*drop Variance;

data lsmdiff0b;

merge lsmdiff0b filterb;

by Trial DataGroup Sample;

if Variance="Pos";

drop Variance;

data lsmdiff;

set lsmdiff0a lsmdiff0b;

Gender="Both";

run;

proc sort;

by Trial DataGroup Sample;

\*proc print;run;

\*need both covparms if allowing 0>p or >100;

data cov0a1;

merge cov0a filtera;

by Trial DataGroup Sample;

if Variance="Pos";

\*drop Variance;

data cov0b1;

merge cov0b filterb;

by Trial DataGroup Sample;

if Variance="Pos";

drop Variance;

data cov;

set cov0a1 cov0b1;

run;

proc sort;

by Trial DataGroup Sample;

run;

/\*

data pred1;

set pred;

if &logflag then do;

pred=exp(pred/100);

&dep=exp(&dep/100);

end;

run;

\*if StudentResid ne .;

title6 "Standardized residuals vs predicteds";

options ls=100 ps=36;

proc plot data=pred1;

plot StudentResid\*pred=Group;

run;

options ls=110 ps=50;

data pred2;

set pred1;

if abs(StudentResid)>3.5;

options ps=52 ls=150;

proc print data=pred2;

var Trial BootSubjN Group VO2maxDelta Resid Studentresid;

title6 "Outliers (Standardized residual >3.5)";

format &dep pred resid 5.&decdep studentresid 5.1;

run;

option ls=110;

\*/

title6 "SD (%) of random effects in original sample, with conf. limits via proc mixed";

&star.title6 "SD (raw) of random effects in original sample, with conf. limits via proc mixed";

title7 "Intercept is pre-test error + shared indiv. responses; xVarExp is net indiv. responses";

title8 "Residual is typical error in the post tests";

data cov1;

set cov0a;

DegFree=2\*Zvalue\*\*2;

a=1;b=1;c=1;

if estimate<0 then a=-1;

if lower<0 then b=-1;

if upper<0 then c=-1;

SD=a\*sqrt(a\*estimate);

lower=b\*sqrt(b\*lower);

upper=c\*sqrt(c\*upper);

array r estimate lower upper;

if &logflag=1 then do over r;

r=100\*exp(r/100)-100;

end;

CLtd=sqrt(upper/lower);

if covparm ne "Residual" then do;

CLtd=.;

CLpm=(upper-lower)/2;

\*DegFree=.;

end;

data cov2;

set cov1;

if Sample=0;

Group=substr(Group,7);

data covpop;

DataGroup="Popn";

CovParm="Intercept";

Subject="BootSubjN";

Group=" ";

SD=sqrt((1-&errorpre\*\*2/(&SD\*\*2\*\*2+&errorpre\*\*2))\*&errorpre\*\*2+&CtlSD\*\*2);\*adjusted for VO2maxPre;

output;

CovParm="xVarExp";

Subject="BootSubjN";

Group=" ";

SD=&ExpSD;

output;

CovParm="Residual";

Subject="";

Group="Control";

SD=&errorpostctl;

output;

Group="Exptal";

SD=&errorpostexp;

output;

run;

data cov3;

set covpop cov2;

proc sort;

by covparm group;

title9 "for first 10 trials";

options ls=110 ps=61;

proc print data=cov3 noobs;

var Trial DataGroup covparm subject group SD lower upper CLpm CLtd alpha;

format SD lower upper CLpm 5.&deceffect CLtd 5.2;

where Trial<11;

run;

\*get conf limits for xVarExp via bootstrapping, to compare with the proc mixed conf limits;

data cov2;

set cov1;

if covparm="xVarExp";

\*proc print data=cov2;run;

proc univariate noprint data=cov2;

var SD;

output out=conflim n=NoOfBootSamples mean=

pctlpts=0.5, 5,50,95,99.5 pctlpre=CL;

by Trial DataGroup;

format CL0\_5--CL99\_5 5.1;

data conflim1;

set conflim;

rename CL50=SD CL5=Lower CL95=Upper;

CLpm=(CL95-CL5)/2;

Alpha=&alpha;

if DataGroup="boot";

data cov3;

set cov1;

if covparm="xVarExp" and Sample=0;

data conflim2;

set cov3 conflim1;

proc sort;

by Trial DataGroup;

title6 "SD of individual responses in original sample, with conf. limits via proc mixed,";

title7 "compared with median and percentile confidence limits from bootstrapped samples";

title8 "for first 10 trials";

options ls=110 ps=61;

proc print data=conflim2 noobs;

var Trial DataGroup NoOfBootSamples SD lower upper CLpm alpha;

format SD lower upper CLpm 5.&deceffect;

where Trial<11;

run;

title6 "Proportions of responders in original and bootstrapped samples";

title7 "via SD for individual responses and mean effect";

\*have to use the cov dataset with all neg vars turned to positive;

data covx;

set cov;

DegFree=2\*Zvalue\*\*2;

a=1;b=1;c=1;

if estimate<0 then a=-1; \*not needed, but keep anyway;

if lower<0 then b=-1;

if upper<0 then c=-1;

SD=a\*sqrt(a\*estimate);

lower=b\*sqrt(b\*lower);

upper=c\*sqrt(c\*upper);

array r estimate lower upper;

if &logflag=1 then do over r;

r=100\*exp(r/100)-100;

end;

CLtd=sqrt(upper/lower);

if covparm ne "Residual" then do;

CLtd=.;

CLpm=(upper-lower)/2;

\*DegFree=.;

end;

if covparm ne "Residual";

data cov3;

merge lsmdiff(keep=Trial DataGroup Sample Gender Estimate StdErr DF)

covx(keep=Trial DataGroup Sample SD DegFree covparm Variance);

by Trial DataGroup Sample;

\*if Gender=\_Gender; \*gives exptal-control for females and males;

SDprop=sqrt(StdErr\*\*2+SD\*\*2);

\*DegFree=999; \*tried this out to improve prediction of proportions;

DFprop=(StdErr\*\*2+SD\*\*2)\*\*2/(StdErr\*\*4/DF+SD\*\*4/DegFree); \*Satterthwaite;

\*DFprop=999; \*tried this out to improve prediction of proportions;

\*DFprop=DF; \*this worked best to decrease PropNegResponders;

\*PropNegResponders too low for large sample size with any of the above;

PropPosResponders=100\*(1-probt(-(Estimate-&MagniThresh)/SDprop,DFprop));

PropNegResponders=100\*probt(-(Estimate+&MagniThresh)/SDprop,DFprop); \*this was an error!;

if covparm="xVarCtl" then do; \*xVarExp must be negative;

if &MagniThresh<Estimate then do;

PropPosResponders=100+(100-PropPosResponders);

PropNegResponders=-PropNegResponders;

end;

if -&MagniThresh<Estimate<&MagniThresh then do;

PropPosResponders=-PropPosResponders;

PropNegResponders=-PropNegResponders;

end;

if Estimate<-&MagniThresh then do;

PropNegResponders=100+(100-PropNegResponders);

PropPosResponders=-PropPosResponders;

end;

end;

PropTrivResponders=100-PropPosResponders-PropNegResponders;

\*options ls=180;

\*proc print;run;

/\*

proc plot data=lsmdiff1;

plot PropPosResponders\*SD;

run;

\*/

proc sort;

by Gender Trial DataGroup;

proc univariate noprint data=cov3;

var PropPosResponders PropTrivResponders PropNegResponders;

output out=conflim1 n=NoOfBootSamples pctlpts=0.5, 5,50,95,99.5 pctlpre=CLpos CLTriv CLneg;

by Gender Trial DataGroup;

format CLpos0\_5--CLneg99\_5 5.1;

data conflim2;

set props1

conflim1(rename=(CLpos50=PropPosResponders CLtriv50=PropTrivResponders CLneg50=PropNegResponders ));

array a CLpos5 CLpos95 CLtriv5 CLtriv95 CLneg5 CLneg95;

if DataGroup="Orig" then do over a;

a=.;

end;

proc sort;

by Gender;

title8 "for first 10 trials";

options ls=120;

proc print noobs;

var Trial Gender DataGroup NoOfBootSamples PropNegResponders CLneg5 CLneg95

PropTrivResponders CLtriv5 CLtriv95 PropPosResponders CLpos5 CLpos95;

\*by Gender;

where Trial<11;

run;

proc sort data=conflim2;

by gender datagroup;

proc means noprint data=conflim2;

by Gender DataGroup;

var PropNegResponders CLneg5 CLneg95 PropTrivResponders CLtriv5 CLtriv95 PropPosResponders CLpos5 CLpos95;

output out=meanprops n=NoOfTrials mean=;

\*where DataGroup ne "boot";

title8 "averaged across all trials";

proc print noobs;

var gender DataGroup NoOfTrials

PropNegResponders CLneg5 CLneg95 PropTrivResponders CLtriv5 CLtriv95 PropPosResponders CLpos5 CLpos95;

format PropNegResponders CLneg5 CLneg95 PropTrivResponders CLtriv5 CLtriv95 PropPosResponders CLpos5 CLpos95 5.1;

run;

\*proc print data=conflim2;run;

title6 "Proportions (%) of confidence intervals that correctly include the true proportions";

data conflim3;

set conflim2;

retain PopPropNegResp PopPropTrivResp PopPropPosResp;

if DataGroup="Popn" then do;

PopPropNegResp=PropNegResponders;

PopPropTrivResp=PropTrivResponders;

PopPropPosResp=PropPosResponders;

end;

CorrectConfIntNegResp=0;

CorrectConfIntTrivResp=0;

CorrectConfIntPosResp=0;

if DataGroup="boot" then do;

if CLneg5<=PopPropNegResp<=CLneg95 then CorrectConfIntNegResp=100;

if CLTriv5<=PopPropTrivResp<=CLTriv95 then CorrectConfIntTrivResp=100;

if CLPos5<=PopPropPosResp<=CLPos95 then CorrectConfIntPosResp=100;

output;

end;

proc means noprint;

var CorrectConfIntNegResp CorrectConfIntTrivResp CorrectConfIntPosResp;

by Gender datagroup;

output out=conflim4 n=NoOfTrials mean=;

proc print;

var Gender DataGroup NoOfTrials CorrectConfIntNegResp CorrectConfIntTrivResp CorrectConfIntPosResp;

format CorrectConfIntNegResp CorrectConfIntTrivResp CorrectConfIntPosResp 5.1;

run;

\*the following will not work when have two or more post tests;

\*consider using predicted values for the mean somehow;

\*can do if use dummies for post1 and post2 instead of nominal;

title6 "Each subject's chance of being a responder in original and bootstrapped samples";

/\*

\*get sign of individual-response variance and merge with predicteds;

\*no, now using analyses with xVarCtl when xVarExp gives negative variance;

data signvar;

set cov;

if covparm="xVarExp";

SignIR=1;

if Estimate<0 then SignIR=-1;

keep Trial DataGroup Sample SignIR;

\*/

/\*

proc print data=pred0a;

\*where Trial=4 and Sample=1;

run;

\*the above showed that some negative variances result in missing values for the SE of the individual predicted values, so cannot use the SEpred for conf limits for individual chances of responses;

\*/

/\*

data predIR;

set pred;

by Trial DataGroup Sample;

PredIndivDelta=lag(Pred)-Pred;

\*PredMeanDelta=lag(PredM)-PredM;

&dep=lag(&dep); \*to carry the observed change score through;

StdErr=sqrt(lag(StdErrPred)\*\*2+StdErrPred\*\*2);

DegFree=(lag(StdErrPred)\*\*2+StdErrPred\*\*2)\*\*2/(lag(StdErrPred)\*\*4/lag(DF)+StdErrPred\*\*4/DF);

\*DegFree=999;

ProbPosResponder=100\*(1-probt(-(PredIndivDelta-&MagniThresh)/StdErr,DegFree));

ProbNegResponder=100\*probt(-(PredIndivDelta+&MagniThresh)/StdErr,DegFree);

ProbTrivResponder=100-ProbPosResponder-ProbNegResponder;

if lag(BootSubjN)=BootSubjN; \*analyze only the experimental group;

run;

\*/

/\*

options ls=190;

proc print data=predIR;

var Trial DataGroup Sample Variance BootSubjN IndivResponse &dep

ProbNegResponder ProbTrivResponder ProbPosResponder StdErr DegFree;

where sample=0;

run;

\*/

/\*

proc sort data=predIR;

by Trial DataGroup SubjectID Gender;

proc means noprint data=predIR;

var VO2maxPre IndivResponse &dep ProbNegResponder ProbTrivResponder ProbPosResponder;

by Trial DataGroup SubjectID Gender;

output out=predIR1 n=NoOfSimulations mean=;

run;

data predIR2;

set predIR1;

IndivResponse=round(IndivResponse,0.00001); \*to avoid an arcane rounding problem;

proc sort data=predIR2;

by Trial descending IndivResponse DataGroup;

title7 "for the first trial only, sorted by the known individual response";

proc print noobs data=predIR2;

var Trial DataGroup NoOfSimulations SubjectID Gender VO2maxPre IndivResponse &dep

ProbNegResponder ProbTrivResponder ProbPosResponder;

format VO2maxPre &dep IndivResponse ProbNegResponder ProbTrivResponder ProbPosResponder 5.1;

where Trial=1;

run;

proc sort data=predIR2;

by Gender Trial DataGroup;

proc means noprint data=predIR2;

var NoOfSimulations IndivResponse &dep ProbNegResponder ProbTrivResponder ProbPosResponder;

by Gender Trial DataGroup;

output out=predIR3 n=NoOfSubjects mean=;

title7 "averaged across all subjects in each trial";

title8 "for the first 10 trials";

proc print noobs data=predIR3;

var Gender Trial DataGroup NoOfSimulations IndivResponse &dep

ProbNegResponder ProbTrivResponder ProbPosResponder;

format NoOfSimulations 5.0 &dep IndivResponse ProbNegResponder ProbTrivResponder ProbPosResponder 5.1;

where Trial<11;

run;

proc sort;

by gender datagroup;

proc means noprint;

by Gender DataGroup;

var NoOfSimulations IndivResponse &dep ProbNegResponder ProbTrivResponder ProbPosResponder;

output out=predIR4 n=NoOfTrials mean=;

title7 "averaged across all trials";

proc print noobs;

var gender DataGroup NoOfTrials NoOfSimulations IndivResponse &dep  
 ProbNegResponder ProbTrivResponder ProbPosResponder;

format NoOfSimulations 5.0 &dep IndivResponse ProbNegResponder ProbTrivResponder ProbPosResponder 5.1;

run;

title6 "Population proportions of responders again, for comparison with the above";

proc print noobs data=props1;

var Gender PropNegResponders PropTrivResponders PropPosResponders;

format \_numeric\_ 5.1;

run;

\*/

options ls=110;

title6 "Least-squares means and differences (%)";

&star.title6 "Least-squares means and differences (raw)";

data lsmdiff1;

set lsm lsmdiff;

array a estimate lower upper;

if &logflag then do over a;

a=exp(a/100);

end;

CLpm=(upper-lower)/2;

proc sort;

by Trial Sample;

title7 "for first 5 trials";

proc print noobs;

var Trial Group \_Group estimate clpm lower upper df alpha;

format estimate clpm lower upper 5.&decdep df 5.0;

\*by Group;

where Trial<6 and Sample=0;

by Trial;

run;

proc sort;

by gender Trial DataGroup Group \_Group;

proc univariate noprint data=lsmdiff1;

var estimate;

output out=conflim1 n=NoOfBootSamples pctlpts=0.5, 5,50,95,99.5 pctlpre=CL;

by Gender Trial DataGroup Group \_Group;

format CL0\_5--CL99\_5 5.1;

data lsmdiff1a;

set lsmdiff1;

if Sample=0;

\*proc print data=conflim1;run;

data conflim2;

set conflim1(rename=(CL50=Estimate CL5=Lower CL95=Upper));

if DataGroup="boot";

CLpm=(Upper-Lower)/2;

data conflim3;

set lsmdiff1a conflim2;

format estimate lower upper CLpm 5.1;

proc sort;

by Gender Trial Group \_Group DataGroup;

options ps=90;

title7 "for original data plus bootstrapped median and confidence limits";

title8 "to check on accuracy of the bootstrapped median and confidence limits";

title9 "for first 5 trials";

proc print noobs;

var Gender Trial DataGroup NoOfBootSamples Group \_Group Estimate CLpm Lower Upper;

where Trial<6;

by Trial;

run;

title6 "MBI for differences in least-squares means for first 5 trials";

\*all the same as for fixed effects, but with est datasets replaced by lsmdiff;

\*and label replaced by Group \_Group or whatever nominal predictors in the proc prints;

\*could do similar for the lsmeans (which would be appropriate when modeling change scores);

data lsmdiff1;

set lsm lsmdiff;

\*if Gender=\_Gender;

length Prob $ 8 Magni $ 4;

MagniThresh=&MagniThresh;

ChancePos=100\*(1-ProbT(-(estimate-abs(MagniThresh))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate+abs(MagniThresh))/StdErr,DF);

if &LogFlag=1 then do;

if Magnithresh>0 then do;

ChancePos=100\*(1-ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF);

end;

else do;

ChancePos=100\*(1-ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF);

end;

end;

ChanceTriv=100-ChancePos-ChanceNeg;

ORPosNeg=ChancePos/(100-ChancePos)/(ChanceNeg/(100-ChanceNeg));

ORNegPos=1/ORPosNeg;

ClinFlag=1; \*want all inferences to be clinical initially;

if index(label,"2SD") then ClinFlag=0; \*covariates definitely need to be non-clinical;

\*clinical inferences;

if clinflag then do;

ChPos=ChancePos; ChNeg=ChanceNeg;

if MagniThresh<0 then do;

ChPos=ChanceNeg; ChNeg=ChancePos;

end;

Prob=""; Magni=""; ClearOrNot="unclear";

if ChNeg<0.5 then do;

ClearOrNot="@25/.5%";

if ChNeg<0.1 then ClearOrNot="@5/.1% ";

if ChanceTriv>25 then Magni="triv";

if ChPos>25 then Magni="bene";

Prob="possibly";

if ChPos>75 or ChanceTriv>75 then Prob="likely ";

if ChPos>95 or ChanceTriv>95 then Prob="v.likely";

if ChPos>99.5 or ChanceTriv>99.5 then Prob="m.likely";

end;

else do; \*i.e., ChNeg>0.5;

if ChPos<25 then do;

ClearOrNot="@25/.5%";

if ChPos<5 then ClearOrNot="@5/.1% ";

if ChanceTriv>25 then Magni="triv";

if ChNeg>25 then Magni="harm";

Prob="possibly";

if ChNeg>75 or ChanceTriv>75 then Prob="likely ";

if ChNeg>95 or ChanceTriv>95 then Prob="v.likely";

if ChNeg>99.5 or ChanceTriv>99.5 then Prob="m.likely";

end;

end;

if ClearOrNot="unclear" and

(MagniThresh>0 and ORPosNeg>25/75/(0.5/99.5) or MagniThresh<0 and ORNegPos>25/75/(0.5/99.5))

then do;

ClearOrNot="OR>66.3";

Magni="bene";

if ChPos>25 then Prob="possibly";

if ChPos>75 then Prob="likely ";

if ChPos>95 then Prob="v.likely";

if ChPos>99.5 then Prob="m.likely";

end;

output;

end;

\*mechanistic inferences;

ClinFlag=0;

ClearOrNot="unclear";

Prob="";

Magni="";

ORPosNeg=.; ORNegPos=.;

if ChanceNeg<5 or ChancePos<5 then ClearOrNot="@90% ";

if ChanceNeg<0.5 or ChancePos<0.5 then ClearOrNot="@99% ";

if ClearOrNot ne "unclear" then do;

Magni="+ive ";

if estimate<0 then Magni="-ive ";

if ChancePos>5 or ChanceNeg>5 then Prob="unlikely";

if ChancePos>25 or ChanceNeg>25 then Prob="possibly";

if ChancePos>75 or ChanceNeg>75 then Prob="likely ";

if ChancePos>95 or ChanceNeg>95 then Prob="v.likely";

if ChancePos>99.5 or ChanceNeg>99.5 then Prob="m.likely";

end;

if ClearOrNot ne "unclear" and ChanceTriv>75 then do;

Magni="triv.";

Prob="likely ";

if ChanceTriv>95 then Prob="v.likely";

if ChanceTriv>99.5 then Prob="m.likely";

end;

\*end;

output;

data lsmdiff2;

set lsmdiff1;

if estimate=0 then do;

estimate=.; magnithresh=.; magni=""; clearornot="";

end;

array a estimate lower upper;

if &logflag then do over a;

a=100\*exp(a/100)-100;

end;

CLpm=(Upper-lower)/2;

rename df=DegFree;

run;

proc sort data=lsmdiff2;

by Gender Trial Group \_Group DataGroup;

title7 "Clinical inferences for original data (Sample=0)";

title8 "Magnithresh is smallest beneficial change";

options ls=145 ps=80;

proc print data=lsmdiff2 noobs;

where clinflag=1 and sample=0 and Trial<6;

var Gender Trial Group \_Group estimate CLpm lower upper alpha DegFree

MagniThresh ChanceNeg ChanceTriv ChancePos ORPosNeg ORNegPos Prob Magni ClearOrNot;

format estimate CLpm lower upper MagniThresh 5.&deceffect Probt best5. ORPosNeg ORNegPos 5.0 ChanceNeg ChanceTriv

ChancePos 5.1 DegFree 5.0;

\*format estimate CLpm lower upper MagniThresh &form Probt best5. ORPosNeg ORNegPos 5.0 ChanceNeg ChanceTriv

ChancePos 5.1 DegFree 5.0;

by Gender Trial;

run;

proc univariate noprint data=lsmdiff2;

var ChanceNeg ChanceTriv ChancePos;

output out=conflim1 n=NoOfBootSamples pctlpts=0.5, 5,50,95,99.5 pctlpre=CLneg CLTriv CLpos;

by Gender Trial Group \_Group DataGroup;

format CLneg0\_5--CLpos99\_5 5.1;

where clinflag=1 and Sample>0;

\*work out conf limits of ChancePos etc. for original sample from non-central t;

\*assume data not log-transformed;

data lsmdiff1a;

set lsmdiff1;

if ClinFlag=1 and Sample=0;

TvalueNeg=-(estimate+abs(MagniThresh))/StdErr;

TvalueNeg0p05=tinv(alpha/2,DF,TvalueNeg);

TvalueNeg0p95=tinv(1-alpha/2,DF,TvalueNeg);

CLNeg5=100\*probt(TvalueNeg0p05,DF);

CLNeg95=100\*probt(TvalueNeg0p95,DF);

TvaluePos=-(estimate-abs(MagniThresh))/StdErr;

TvaluePos0p05=tinv(alpha/2,DF,TvaluePos);

TvaluePos0p95=tinv(1-alpha/2,DF,TvaluePos);

CLpos95=100\*(1-probt(TvaluePos0p05,DF)); \*needs opposite of CLneg;

CLpos5=100\*(1-probt(TvaluePos0p95,DF)); \*ditto;

data conflim2;

set lsmdiff1a conflim1(rename=(CLpos50=ChancePos CLtriv50=ChanceTriv CLneg50=ChanceNeg));

array a CLpos5 CLpos95 CLtriv5 CLtriv95 CLneg5 CLneg95;

/\*

if DataGroup="Orig" then do over a;

a=.;

end;

\*/

proc sort;

by Gender trial Group \_Group DataGroup;

options ps=90;

title7 "MBI probabilities with confidence limits via non-central t for original sample and bootstrapping";

title8 "(to show that sample-derived probabilities have confidence limits).";

title9 "Note: cannot derive confidence limits for ChancesTriv via t statistic,";

title10 "because cannot express ChancesTriv as a function of a single t value.";

proc print noobs;

var Gender Trial DataGroup Group \_Group NoOfBootSamples ChanceNeg CLneg5 CLneg95 ChanceTriv CLtriv5 CLtriv95

ChancePos CLpos5 CLpos95;

where Trial<6;

by Gender Trial;

run;

\*FIXED EFFECTS;

title6 "Fixed effects (%)";

&star.title6 "Fixed effects (raw)";

title7 "for original sample in first 5 trials";

data est1;

set est0a;

if estimate=0 then estimate=.;

array a estimate lower upper;

if &logflag=1 then do over a;

a=100\*exp(a/100)-100;

end;

CLpm=(Upper-lower)/2;

\*proc sort;

\*by label;

options ls=110 ps=90;

proc print data=est1 noobs;

var Trial Label estimate CLpm lower upper alpha DF ;

format estimate stderr CLpm lower upper 5.&deceffect Probt best5. DF 5.0;

\*by label;

by Trial;

where Trial<6 and Sample=0;

run;

\*magnitude-based inferences for fixed effects;

\*clin and non-clin MBIs are output and listed separately;

title6 "MBI for fixed effects";

data est1;

set est0a;

length Prob $ 8 Magni $ 4;

MagniThresh=&MagniThresh;

ChancePos=100\*(1-ProbT(-(estimate-abs(MagniThresh))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate+abs(MagniThresh))/StdErr,DF);

if &LogFlag=1 then do;

if Magnithresh>0 then do;

ChancePos=100\*(1-ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF);

end;

else do;

ChancePos=100\*(1-ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF);

end;

end;

ChanceTriv=100-ChancePos-ChanceNeg;

ORPosNeg=ChancePos/(100-ChancePos)/(ChanceNeg/(100-ChanceNeg));

ORNegPos=1/ORPosNeg;

ClinFlag=1; \*want all inferences to be clinical initially;

if index(label,"2SD") then ClinFlag=0; \*covariates definitely need to be non-clinical;

\*clinical inferences;

if clinflag then do;

ChPos=ChancePos; ChNeg=ChanceNeg;

if MagniThresh<0 then do;

ChPos=ChanceNeg; ChNeg=ChancePos;

end;

Prob=""; Magni=""; ClearOrNot="unclear";

if ChNeg<0.5 then do;

ClearOrNot="@25/.5%";

if ChNeg<0.1 then ClearOrNot="@5/.1% ";

if ChanceTriv>25 then Magni="triv";

if ChPos>25 then Magni="bene";

Prob="possibly";

if ChPos>75 or ChanceTriv>75 then Prob="likely ";

if ChPos>95 or ChanceTriv>95 then Prob="v.likely";

if ChPos>99.5 or ChanceTriv>99.5 then Prob="m.likely";

end;

else do; \*i.e., ChNeg>0.5;

if ChPos<25 then do;

ClearOrNot="@25/.5%";

if ChPos<5 then ClearOrNot="@5/.1% ";

if ChanceTriv>25 then Magni="triv";

if ChNeg>25 then Magni="harm";

Prob="possibly";

if ChNeg>75 or ChanceTriv>75 then Prob="likely ";

if ChNeg>95 or ChanceTriv>95 then Prob="v.likely";

if ChNeg>99.5 or ChanceTriv>99.5 then Prob="m.likely";

end;

end;

if ClearOrNot="unclear" and

(MagniThresh>0 and ORPosNeg>25/75/(0.5/99.5) or MagniThresh<0 and ORNegPos>25/75/(0.5/99.5))

then do;

ClearOrNot="OR>66.3";

Magni="bene";

if ChPos>25 then Prob="possibly";

if ChPos>75 then Prob="likely ";

if ChPos>95 then Prob="v.likely";

if ChPos>99.5 then Prob="m.likely";

end;

output;

end;

\*mechanistic inferences;

ClinFlag=0;

ClearOrNot="unclear";

Prob="";

Magni="";

ORPosNeg=.; ORNegPos=.;

if ChanceNeg<5 or ChancePos<5 then ClearOrNot="@90% ";

if ChanceNeg<0.5 or ChancePos<0.5 then ClearOrNot="@99% ";

if ClearOrNot ne "unclear" then do;

Magni="+ive ";

if estimate<0 then Magni="-ive ";

if ChancePos>5 or ChanceNeg>5 then Prob="unlikely";

if ChancePos>25 or ChanceNeg>25 then Prob="possibly";

if ChancePos>75 or ChanceNeg>75 then Prob="likely ";

if ChancePos>95 or ChanceNeg>95 then Prob="v.likely";

if ChancePos>99.5 or ChanceNeg>99.5 then Prob="m.likely";

end;

if ClearOrNot ne "unclear" and ChanceTriv>75 then do;

Magni="triv.";

Prob="likely ";

if ChanceTriv>95 then Prob="v.likely";

if ChanceTriv>99.5 then Prob="m.likely";

end;

\*end;

output;

data est2;

set est1;

if estimate=0 then do;

estimate=.; magnithresh=.; magni=""; clearornot="";

end;

array a estimate lower upper;

if &logflag then do over a;

a=100\*exp(a/100)-100;

end;

CLpm=(Upper-lower)/2;

rename df=DegFree;

run;

/\*

options ls=145 ps=0;

title7 "Clinical inferences"; \*not used here;

title8 "Magnithresh is smallest beneficial change";

proc print data=est2 noobs;

where clinflag=1;

var label estimate CLpm lower upper alpha DegFree

MagniThresh ChanceNeg ChanceTriv ChancePos ORPosNeg ORNegPos Prob Magni ClearOrNot;

format estimate CLpm lower upper MagniThresh 5.&dec Probt best5. ORPosNeg ORNegPos 5.0 ChanceNeg ChanceTriv

ChancePos 5.1 DegFree 5.0;

\*format estimate CLpm lower upper MagniThresh &form Probt best5. ORPosNeg ORNegPos 5.0 ChanceNeg ChanceTriv

ChancePos 5.1 DegFree 5.0;

run;

\*/

options ls=130 ps=90;

title7 "Non-clinical inferences for covariates";

title8 "Magnithresh is smallest change";

title9 "for original sample in first 5 trials";

proc print data=est2 noobs;

where clinflag=0 and Trial<6 and Sample=0;

var Trial label estimate CLpm lower upper alpha DegFree

MagniThresh ChanceNeg ChanceTriv ChancePos Prob Magni ClearOrNot;

format estimate CLpm lower upper MagniThresh 5.&decdep Probt best5. ChanceNeg ChanceTriv

ChancePos 5.1 DegFree 5.0;

by Trial;

run;

options ls=110;

\*this sound output does not work in SAS Studio;

data \_null\_;

call sound(440,200);

call sound(622,200);

call sound(880,200);

run;